题解 | #同步FIFO#

`timescale 1ns/1ns

/**********************************RAM************************************/
module dual_port_RAM #(parameter DEPTH = 16,
					   parameter WIDTH = 8)(
	 input wclk
	,input wenc
	,input [$clog2(DEPTH)-1:0] waddr  
	,input [WIDTH-1:0] wdata      	
	,input rclk
	,input renc
	,input [$clog2(DEPTH)-1:0] raddr  
	,output reg [WIDTH-1:0] rdata 		
);

reg [WIDTH-1:0] RAM_MEM [0:DEPTH-1];

always @(posedge wclk) begin
	if(wenc)
		RAM_MEM[waddr] <= wdata;
end 

always @(posedge rclk) begin
	if(renc)
		rdata <= RAM_MEM[raddr];
end 

endmodule  

/**********************************SFIFO************************************/
module sfifo#(
	parameter	WIDTH = 8,
	parameter 	DEPTH = 16
)(
	input 					clk		, 
	input 					rst_n	,
	input 					winc	,
	input 			 		rinc	,
	input 		[WIDTH-1:0]	wdata	,

	output reg				wfull	,
	output reg				rempty	,
	output wire [WIDTH-1:0]	rdata
);
	reg [$clog2(DEPTH):0] p_read,p_write;

	always @(posedge clk or negedge rst_n) begin
		if(~rst_n) begin
			p_write <= 0;
		end
		else if(winc && !wfull ) begin
			p_write <= p_write + 1'b1;
		end
	end

	always @(posedge clk or negedge rst_n) begin
		if(~rst_n) begin
			p_read <= 0;
		end
		else if(rinc && !rempty) begin
			p_read <= p_read + 1'b1;
		end
	end

	always @(posedge clk or negedge rst_n) begin
		if(~rst_n) begin
			rempty <= 1'b0;
		end
		else if(p_read == p_write) begin
			rempty <= 1'b1;
		end
		else begin
			rempty <= 1'b0;
		end
	end

	always @(posedge clk or negedge rst_n) begin
		if(~rst_n) begin
			wfull <= 1'b0;
		end
		else if(p_write == p_read + DEPTH) begin
			wfull <= 1'b1;
		end
		else begin
			wfull <= 1'b0;
		end
	end


    dual_port_RAM #(DEPTH,WIDTH) u0(
		.wclk(clk),
		.wenc(winc&(!wfull)),
		.waddr(p_write),
		.wdata(wdata),
		.rclk(clk),
		.renc(rinc&(!rempty)),
		.raddr(p_read),
		.rdata(rdata)
	);
endmodule

看评论区做出来的。提供一个错误做法：

第一次做的时候p_write和p_read与waddr和raddr位宽一样，判断满的条件是p_write == p_read - 1'b1。

这样做会有一个问题——p_write == p_read - 1'b1这个位置p_write还没有写入数据，但是FIFO判断满了，实际上循环过后当p_write == p_read才是真正的满，但是这个条件与判断空的条件冲突了。

上述正确做法给p_write和p_read多加了1bit，是为了可以将判断空的条件与判断满的条件区分开来。当p_write == p_read，说明写指针并没有超过读指针一圈，此时为空。当p_write == p_read + DEPTH，说明写指针超过读指针一圈，判断为满。实际上无论满还是空双口RAM的读写地址都指向了一个位置。